Thinking About Using VBA's IsNumeric Function? Read this first.

**Rick Rothstein** · 03-29-2015, 02:28 PM

I have posted the following many times over the last 10 years or so in responding to old newsgroup and current forum questions. I decided to post it here for all to see.

I usually try and steer people away from using IsNumeric to "proof" supposedly numeric text. Consider this (also see note below):

Code:

ReturnValue = IsNumeric("($1,23,,3.4,,,5,,D56$)$$$$$$$")

Most people would not expect THAT to return True. IsNumeric has some "flaws" in what it considers a proper number and what most programmers are looking for.

I had a short tip published by Pinnacle Publishing in their Visual Basic Developer magazine that covered some of these flaws. Originally, the tip was free to view but is now viewable only by subscribers.. Basically, it said that IsNumeric returned True for things like -- currency symbols being located in front or in back of the number as shown in my example (also applies to plus, minus and blanks too); numbers surrounded by parentheses as shown in my example (some people use these to mark negative numbers); numbers containing any number of commas before a decimal point as shown in my example; numbers in scientific notation (a number followed by an upper or lower case "D" or "E", followed by a number equal to or less than 307 -- the maximum power of 10 in VB); and Octal/Hexadecimal numbers (&H for Hexadecimal, &O or just & in front of the number for Octal).

NOTE:
======
In the above example and in the referenced tip, I refer to $ signs and commas and dots -- these were meant to refer to your currency, thousands separator and decimal point symbols as defined in your local settings -- substitute your local regional symbols for these if appropriate.

As for your question about checking numbers, here are two functions that I have posted in the past for similar questions..... one is for digits only and the other is for "regular" numbers (the code is simple enough that it can be pulled from the function "housing" and used directly inside your own code):

Code:

Function IsDigitsOnly(Value As String) As Boolean
    IsDigitsOnly = Len(Value) > 0 And Not Value Like "*[!0-9]*"
End Function

Function IsNumber(ByVal Value As String) As Boolean
    '   Leave the next statement out if you don't
    '   want to provide for plus/minus signs
    If Value Like "[+-]*" Then Value = Mid$(Value, 2)
    IsNumber = Not Value Like "*[!0-9.]*" And Not Value Like "*.*.*" And Len(Value) > 0 And Value <> "."
End Function

Here are revisions to the above functions that deal with the local settings for decimal points (and thousand's separators) that are different than used in the US (this code works in the US too, of course).

Code:

Function IsNumber(ByVal Value As String) As Boolean
  Dim DP As String
  '   Get local setting for decimal point
  DP = Format$(0, ".")
  '   Leave the next statement out if you don't
  '   want to provide for plus/minus signs
  If Value Like "[+-]*" Then Value = Mid$(Value, 2)
  IsNumber = Not Value Like "*[!0-9" & DP & "]*" And Not Value Like "*" & _
             DP & "*" & DP & "*" And Len(Value) > 0 And Value <> DP
End Function

I'm not as concerned by the rejection of entries that include one or more thousand's separators, but we can handle this if we don't insist on the thousand's separator being located in the correct positions (in other words, we'll allow the user to include them for their own purposes... we'll just tolerate their presence).

Code:

Function IsNumber(ByVal Value As String) As Boolean
  Dim DP As String
  Dim TS As String
  '   Get local setting for decimal point
  DP = Format$(0, ".")
  '   Get local setting for thousand's separator
  '   and eliminate them. Remove the next two lines
  '   if you don't want your users being able to
  '   type in the thousands separator at all.
  TS = Mid$(Format$(1000, "#,###"), 2, 1)
  Value = Replace$(Value, TS, "")
  '   Leave the next statement out if you don't
  '   want to provide for plus/minus signs
  If Value Like "[+-]*" Then Value = Mid$(Value, 2)
  IsNumber = Not Value Like "*[!0-9" & DP & "]*" And Not Value Like "*" & _
             DP & "*" & DP & "*" And Len(Value) > 0 And Value <> DP
End Function

**DocAElstein** · 03-23-2021, 11:54 PM

Thanks for these ideas, Rick. - I just thought I would mention that, as I passed this Blog post on just now, I saw in that Thread something that might be worth mentioning here in passing, which is that Hans offered an Excel Worksheet function alternative, Application.IsNumber( ) , which seems more likely to give results closer to what most people would expect.
If I understand correctly the main difference between the two functions can be thought of approximately as
IsNumeric( ) is True if it thinks it can convert the given text into a number, whereas
Application.IsNumber( ) is more likely to be True only if the passed thing looks like a number, ( it won't , for example . convert a text into a number, even anything simple like "2" )

That is just an approximate conclusion as I have not investigated thoroughly both functions yet…

The intelligence behind IsNumeric( ) is perhaps a different one to ours, and perhaps as a compromise for efficiency does not thoroughly check for correctness, but rather looks for some allowed characters that might be used in some number formats,
( and it allows a text that has a number format,
( whereas Application.IsNumber( ) doesn’t: For example Application.IsNumber("1") is false because "1" is text )
IsNumeric("1") is True)

Alan

( Edit P.S. I geuss you will need to be in Excel or else load the Excel library in order to use Application.IsNumber( ) )

**Rick Rothstein** · 03-24-2021, 07:07 AM

**DocAElstein** · 03-24-2021, 02:29 PM

Hello Rick

I personally generally prefer to use some basic VBA and/or VB string manipulation stuff in a User Defined Function, although I suppose, theoretically at least, an in built function might be more efficient sometimes, assuming the person who developed it knew what he was doing.
( A UDF I would also prefer to develop in an older Office version, using more fundamental things, as it’s a good chance then of always working also in newer office versions.
I am personally rather annoyed by Microsoft thinking that development is introducing new Functions, which then give backward compatibility problems, or coding no longer works sometimes as it did…. )

I also like that use of the Like operator. I have not used that Like much. I should get clued up on it. It looks like a useful extra tool to have when doing string manipulation and analysis.
( Often in the past I have got rather confused with other “Wild” card thing syntaxes , like in Find and Replace strings, Reg Ex and co. etc.
But a quick google just now on the Like operator reveals that its not so complicated, and should not take long to learn. ( Maybe a post on the Like operator could be a useful addition at excelfox tips for one of us to do sometime ) )